Routines
Prev: 53AB Up: Map Next: 53F4
53B1: Clear the screen and request the input method (keyboard, joystick, Int2)
Used by the routine at 55A0.
53B1 LD BC,$0280 INK 0: PAPER 6 for the top 20 lines of screen
53B4 LD DE,$5801
53B7 LD HL,$5800
53BA LD (HL),$30
53BC LDIR
53BE LD C,$80 INK 6: PAPER 6 for the bottom 4 lines of screen
53C0 LD (HL),$36
53C2 LDIR
53C4 CALL $53AB Make a short beep
53C7 LD H,$40 Clear the top two-thirds of the display file
53C9 LD D,H
53CA LD (HL),L
53CB LD B,$10
53CD LDIR
53CF LD B,$A0 Clear the remainder of the screen, except the bottom 3 lines (which contain machine code)
53D1 LD (HL),C
53D2 INC L
53D3 DJNZ $53D1
53D5 LD L,B
53D6 INC H
53D7 BIT 3,H
53D9 JR Z,$53CF
53DB LD A,$80 Set the column of the play area at the far left of the screen to 128
53DD LD ($7FFF),A
53E0 NOP
53E1 CALL $50A0 Clear character buffer 0xD6 (for no good reason)
53E4 LD A,$F6 Message 0xF6: 'None/Cursor/Kempston/Int2? (N,C,K or I)'
53E6 LD HL,$4040 Print this message
53E9 CALL $50BC
53EC LD HL,$5C3B Clear bit 5 at 5C3B, ready for future keypresses
53EF RES 5,(HL)
53F1 JP $54A0
Prev: 53AB Up: Map Next: 53F4