Routines
Prev: $379F Up: Map Next: $3868
$3805: Prepare sprites #0-#6 for the speech bubble with the lip on the right
Used by the routine at $2387.
Input
A Screen pixel x-coordinate of the lip section
$3805 STA $D006 Set the x-coordinates of sprites #3 and #5 (bits 0-7).
$3808 STA $D00A
$380B SEC Subtract 56 from this x-coordinate.
$380C SBC #$38
$380E STA $D004 Make this the x-coordinate of sprites #2 and #4 (bits 0-7).
$3811 STA $D008
$3814 BCC $381B Branch unless the x-coordinate is greater than 255.
$3816 LDA #$FF Set bit 8 of the x-coordinates of sprites #0-#7.
$3818 STA $D010
$381B LDA $D004 Pick up the x-coordinate of sprite #2.
$381E CLC Add 8 to this x-coordinate.
$381F ADC #$08
$3821 STA $D000 Make this the x-coordinate of sprites #0 and #6 (bits 0-7).
$3824 STA $D00C
$3827 BCC $3831 Branch unless the x-coordinate is greater than 255.
$3829 LDA #$43 Set bit 8 of the x-coordinates of sprites #0, #1 and #6.
$382B ORA $D010
$382E STA $D010
$3831 LDA $D00C Pick up the x-coordinate of sprite #6 (bits 0-7).
$3834 CLC Add 24 to this x-coordinate.
$3835 ADC #$18
$3837 STA $D002 Make this the x-coordinate of sprite #1 (bits 0-7).
$383A BCC $3844 Branch unless the x-coordinate is greater than 255.
$383C LDA #$02 Set bit 8 of the x-coordinate of sprite #1.
$383E ORA $D010
$3841 STA $D010
$3844 LDA #$29 Set the pointer for sprite #0 to $29. This points at $CA40 (the first middle outline section of the speech bubble, copied from $3E40).
$3846 STA $CFF8
$3849 LDA #$2A Set the pointer for sprite #1 to $2A. This points at $CA80 (the second middle outline section of the speech bubble, copied from $3E80).
$384B STA $CFF9
$384E LDA #$21 Set the pointer for sprite #2 to $21. This points at $C840 (the leftmost outline section of the speech bubble, copied from $3C40).
$3850 STA $CFFA
$3853 LDA #$27 Set the pointer for sprite #3 to $27. This points at $C9C0 (the right-hand lip outline section of the speech bubble, copied from $3DC0).
$3855 STA $CFFB
$3858 LDA #$20 Set the pointer for sprite #4 to $20. This points at $C800 (the filled in leftmost section of the speech bubble, copied from $3C00).
$385A STA $CFFC
$385D LDA #$26 Set the pointer for sprite #5 to $26. This points at $C980 (the filled in right-hand lip section of the speech bubble, copied from $3D80).
$385F STA $CFFD
$3862 LDA #$28 Set the pointer for sprite #6 to $28. This points at $CA00 (the filled in middle section of the speech bubble, copied from $3E00).
$3864 STA $CFFE
$3867 RTS
Prev: $379F Up: Map Next: $3868